Stem File Versioning

Bump Version by Folder

Keep the filenames of the audio files identical apart from the version number at the end. They can be in separate folders or the same folder.

This script will ask you to select the folder of the new stem files, and request the current and new version numbers. It is important that you enter the correct number of digits, including leading zeroes. "1" will not be treated the same as "01". The old and new version do not need to have the same number of digits; it is possible to update from "01" to "2" or even from "005" to "04".

The script then re-targets your audio cues. This way, you don't lose the integrated fade envelope and other cue settings you've already built, but can batch re-target all your stems quickly and save tedious busy-work.

WARNING

Do not use slashes in your filenames. This script uses 'POSIX' /paths/to/files so adding slashes to the file names will break the current version of this script.

WARNING

Make sure to use the correct number of digits / leading zeroes for both the old version and the new version numbers.

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v250227-01

-- ALERT: Do not use slashes in your filenames

tell application id "com.figure53.QLab.5" to tell front workspace
	set theSelection to (selected as list)
	
	-- Request folder
	set theFolder to the POSIX path of (choose folder with prompt "Which folder are the new stems in?")
	
	-- Request old version
	set oldRequest to display dialog "What is the current version number? Include leading zeroes if needed." default answer "01" buttons {"Cancel", "Continue"} default button "Continue"
	set oldVersion to text returned of oldRequest
	if button returned of oldRequest is not "Continue" then return
	set oldVersionLength to count of oldVersion
	
	-- Request new version
	set newRequest to display dialog "What is the new version number? Include leading zeroes if needed." default answer oldVersion buttons {"Cancel", "Continue"} default button "Continue"
	set newVersion to text returned of newRequest
	if button returned of newRequest is not "Continue" then return
	set newVersionLength to count of newVersion
	
	
	repeat with eachCue in theSelection
		
		if q type of eachCue is "Audio" then
			
			set theName to q name of eachCue
			
			-- Get POSIX path of current target		
			set theTarget to (file target of eachCue)
			set originalPath to the POSIX path of theTarget
			
			-- Determine name of file without full path
			set reversedPath to reverse of characters of originalPath as string
			set fileName to text (1 - (offset of "/" in reversedPath)) thru -1 of originalPath -- "bass v02.wav"
			
			-- Break up string components
			set lastChars to text -6 thru -1 of fileName
			set thePos to ((6 - ((offset of "." in lastChars) - 2)) * -1)
			set theExt to text (offset of "." in lastChars) thru -1 of lastChars -- ".wav"
			set theTrunk to text 1 thru thePos of fileName -- "bass v02"
			
			-- Calculate new file name
			set plainTrunk to text 1 thru (-1 - oldVersionLength) of theTrunk
			set newFileName to plainTrunk & newVersion & theExt
			
			-- Calculate new target
			set newTarget to theFolder & newFileName
			
			-- Set new target
			set file target of eachCue to (POSIX file newTarget)
		end if
	end repeat
	
end tell

Reveal File Target

This will reveal the file target of the last selected Audio cue in the Finder. QLab also provides a built-in tool for this in Tools > Reveal target file in Finder but it does not have an associated hotkey.

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v211121-01

tell application id "com.figure53.QLab.5" to tell front workspace
	set theCue to last item of (selected as list)
	if q type of theCue is "Audio" then
		set fileTarget to file target of theCue
		tell application "Finder"
			reveal fileTarget
			activate
		end tell
	end if
end tell

Bump Version by File Name

This script is not as good as the one above as it is more restrictive. But feel free to try it if you want....

You have a group of audio cues, which are stems for a piece of music. The filenames all end in "v03" or something similar. You just bounced new stem files called "v04" but you don't want to tediously manually re-target them all. No one wants to hold for sound. Use this script instead! All the "v04" files must be located in the same folder as the "v03" files.

USER PARAMETERS

versionLength is the number of digits used for version numbers. 2 is recommended: v1 / v01

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v250227-01

set versionLength to 2 -- How many digits for versioning? v1 / v01, 2 digits recommended

tell application id "com.figure53.QLab.5" to tell front workspace
	set theSelection to (selected as list)
	repeat with eachCue in theSelection
		
		if q type of eachCue is "Audio" then
			
			set theName to q name of eachCue
			
			-- Get POSIX path of current target		
			set theTarget to (file target of eachCue)
			set originalPath to the POSIX path of theTarget
			
			-- Break up string components
			set lastChars to text -6 thru -1 of originalPath
			set thePos to ((6 - ((offset of "." in lastChars) - 2)) * -1)
			set theExt to text (offset of "." in lastChars) thru -1 of lastChars
			set theTrunk to text 1 thru thePos of originalPath
			
			-- Determine old version number
			set oldVersion to (text (versionLength * -1) thru -1 of theTrunk) as integer
			
			-- Set new number with leading zero if needed
			set newVersion to (oldVersion + 1) as string
			if (count newVersion) < versionLength then
				set leadingNeeded to versionLength - (count newVersion)
				repeat leadingNeeded times
					set newVersion to ("0" & newVersion)
				end repeat
			end if
			
			-- Generate path to new file
			set newTarget to ((text 1 thru (-1 - versionLength) of theTrunk) & newVersion & theExt)
			
			-- Retarget cue
			set file target of eachCue to (POSIX file newTarget)
			
		end if
	end repeat
	
end tell