Console Recalls

How to use

These scripts operate together as a set.

IMPORTANT

DiGiCo SD Theatre consoles do not have a default MIDI-to-snapshot routing map out of the box.

This set of scripts assumes a MIDI routing scheme where:

• Snapshots are numbered XX.YY
• Related MIDI triggers are Control Changes with Control Number XX and Control Value YY

You do not have to stick to this scheme in an absolute manner - just as a starting point for generating triggers. The generated trigger list can be altered and supplemented manually after initial creation.

1. Run the "list generator" script (preferably from Script Editor) in a new empty "Console Cues" cue list
2. Add the "Add Snapshot to Cue List" scripts to your "Hotkeys" cue list
3. In your Main cue list, use the hotkey scripts to add console recalls to your show

DiGiCo Control-Change List Generator

USER PARAMETERS

userPrefix is a cue-number prefix for the generated MIDI cues and should not be left blank

userNamePrefix is a cue-name prefix for the generated MIDI cues

showMIDIInfo is a boolean which toggles including the MIDI details in the cue names of the generated cues

userCount is the number of snapshot triggers you need to generate. The current version of this script does not work with a value above 384.

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v250207-01

set userPrefix to "sd"
set userCueName to "SD Snapshot "
set userShowMIDIInfo to true
set userCount to 400 -- The number of snapshot triggers to generate. Do not set above 400.


tell application id "com.figure53.QLab.5" to tell front workspace
	set i to 1
	set scene to 1
	
	repeat userCount times
		make type "MIDI"
		set newCue to last item of (selected as list)
		
		set q number of newCue to userPrefix & (scene)
		
		set command of newCue to control_change
		
		if i is less than 100 then
			set byteOne to 16
			set byteTwo to i
		else if i is less than 200 then
			set byteOne to 17
			set byteTwo to (i - 100)
		else if i is less than 300 then
			set byteOne to 18
			set byteTwo to (i - 200)
		else
			set byteOne to 19
			set byteTwo to (i - 300)
		end if
		
		set channel of newCue to 16
		set byte one of newCue to byteOne
		set byte two of newCue to byteTwo
		
		
		if userShowMIDIInfo then
			set q name of newCue to userCueName & (scene) & " (Ch 16 / CC " & byteOne & " - " & byteTwo & ")"
		else
			set q name of newCue to userCueName & (scene)
		end if
		
		set i to i + 1
		set scene to scene + 1
	end repeat
	
end tell

Add Snapshot to Cue List

USER PARAMETERS

userColor see list generator script above - must match

userPrefix see list generator script above - must match

userNameParent If set to 'true', the parent group of the newly created cue will be color coded and have a suffix added to indicate the presence of a console cue

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v250217-02

set userColor to "Purple"
set userPrefix to "sd"
set userCueName to "Desk Cue"
set userNameParent to true

tell application id "com.figure53.QLab.5" to tell front workspace
	try
		
		set theSelection to first item of (selected as list)
		
		set userInput to display dialog "Snapshot?" default answer "" buttons {"Cancel", "Continue"} default button "Continue"
		set theSnapshot to text returned of userInput
		if button returned of userInput is not "Continue" then return
		
		make type "Start"
		set theStart to last item of (selected as list)
		set theParent to parent of theStart
		set cue target of theStart to cue (userPrefix & theSnapshot)
		set q color of theStart to userColor
		
		if q type of theSelection is "Group" and q type of parent of theSelection is "Cue List" then
			move cue id (uniqueID of theStart) to beginning of cue id (uniqueID of theSelection) of parent of theSelection
			if userNameParent then
				set parentName to q name of theSelection
				set q name of theSelection to parentName & " | " & userCueName & " " & theSnapshot
				if q color of theSelection is "None" then set q color of theSelection to userColor
			end if
			set selected to theSelection
			
		end if
		
		if userNameParent and q type of theParent is "Group" then
			set parentName to q name of theParent
			set q name of theParent to parentName & " | " & userCueName & " " & theSnapshot
			if q color of theParent is "None" then set q color of theParent to userColor
		end if
		
	on error
		return
	end try
end tell

Add Snapshot Group to Cue List

USER PARAMETERS

userColor see list generator script above - must match

userPrefix see list generator script above - must match

userNameParent If set to 'true', the parent group of the newly created cue will be color coded and have a suffix added to indicate the presence of a console cue

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v250217-01

set userColor to "Purple"
set userPrefix to "sd"
set userCueName to "DiGiCo Snapshot"
set userNameParent to true

tell application id "com.figure53.QLab.5" to tell front workspace
	try
		set userInput to display dialog "Snapshot?" default answer "" buttons {"Cancel", "Continue"} default button "Continue"
		set theSnapshot to text returned of userInput
		if button returned of userInput is not "Continue" then return
		
		make type "Start"
		set theStart to last item of (selected as list)
		set cue target of theStart to cue (userPrefix & theSnapshot)
		set q color of theStart to userColor
		
		make type "Group"
		set theGroup to last item of (selected as list)
		set q name of theGroup to userCueName & " " & theSnapshot
		set q color of theGroup to userColor
		
		move cue id (uniqueID of theStart) of parent of theStart to end of cue id (uniqueID of theGroup)
		
		set theParent to parent of theGroup
		
		if userNameParent and q type of theParent is "Group" then
			set parentName to q name of theParent
			set q name of theParent to parentName & " | " & userCueName & " " & theSnapshot
			if q color of theParent is "None" then set q color of theParent to userColor
		end if
		
		
	on error
		return
	end try
end tell