Create Triggers

Create OSC Trigger for Cue X

This is an edge-use thing and only useful if you need QLab to trigger itself via OSC for some particular reason.

Example:

LX is triggering some (but not all) QLab cues, in a way that forces the QLab user to conform to the LX cue numbering. All cues in the Main cue stack are given a prefix or suffix to avoid unintended triggers from LX. All LX-triggered QLab cues live in a dedicated cue list, and this script is used to generate the contents of that cue list quickly, without the user needing to type the prefix or suffix each time they add a cue to the stack.

USER PARAMETERS

userPatch is the OSC output patch name of the generated cues

userPrefix is the cue number prefix, if needed (edge use case)

userSuffix is the cue number suffix, if needed (edge use case)

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v211121-01

set userPatch to "This QLab"
set userPrefix to ""
set userSuffix to "."

tell application id "com.figure53.QLab.5" to tell front workspace
	try
		set userInput to display dialog "QLab Cue?" default answer "" buttons {"Cancel", "Continue"} default button "Continue"
		set cueNumber to text returned of userInput
		if button returned of userInput is "Continue" then
			make type "Network"
			set theNetwork to last item of (selected as list)
			set network patch name of theNetwork to userPatch
			set custom string of theNetwork to ("/cue/" & userPrefix & cueNumber & userSuffix & "/go")
		end if
	on error
		return
	end try
end tell

Create OSC Triggers for Selected

Creates a group of network cues which target the selected cues

USER PARAMETERS

userPatch is the network patch name which points back to the local instance of QLab (typically localhost:53000)

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v230416-01

set userPatch to "This QLab"

tell application id "com.figure53.QLab.5" to tell front workspace
	set theSelection to (selected as list)
	set newCues to {}
	repeat with eachCue in theSelection
		set theQ to q number of eachCue
		set selected to eachCue
		if theQ is not "" then
			make type "Network"
			set newCue to last item of (selected as list)
			set network patch name of newCue to userPatch
			set custom string of newCue to ("/cue/" & theQ & "/start")
			set end of newCues to newCue
		end if
	end repeat
	if length of newCues is not 0 then
		make type "Group"
		set theGroup to last item of (selected as list)
		repeat with eachCue in newCues
			move cue id (uniqueID of eachCue) of parent of eachCue to end of theGroup
		end repeat
	end if
end tell

Create Start Triggers for Selected

Creates a group of Start cues which target the selected cues

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v230416-01

tell application id "com.figure53.QLab.5" to tell front workspace
	set theSelection to (selected as list)
	set newCues to {}
	repeat with eachCue in theSelection
		set theQ to q number of eachCue
		set selected to eachCue
		make type "Start"
		set newCue to last item of (selected as list)
		set cue target of newCue to eachCue
		set end of newCues to newCue
	end repeat
	if length of newCues is not 0 then
		make type "Group"
		set theGroup to last item of (selected as list)
		repeat with eachCue in newCues
			move cue id (uniqueID of eachCue) of parent of eachCue to end of theGroup
		end repeat
	end if
end tell

Create LX MSC Cues

Creates an MSC trigger based on user parameters and dialog input

-- For help, bug reports, or feature suggestions, please visit https://github.com/samschloegel/qlab-scripts
-- Built for QLab 5. v250217-01

set userListNumber to 1
set userDevID to 1
set userColor to "Green"
set userShowListNumber to false
set userNameParent to true

tell application id "com.figure53.QLab.5" to tell front workspace
	try
		set theSelection to first item of (selected as list)
		
		set userInput to display dialog "Cue Number?" default answer "" buttons {"Cancel", "Continue"} default button "Continue"
		if button returned of userInput is "Cancel" then return
		if text returned of userInput is "" then return
		set theNumber to text returned of userInput
		
		make type "MIDI"
		set newMIDI to last item of (selected as list)
		set theParent to parent of newMIDI
		
		set message type of newMIDI to msc
		set deviceID of newMIDI to userDevID
		set command format of newMIDI to 1
		set q_number of newMIDI to theNumber
		set q_list of newMIDI to userListNumber
		
		set q color of newMIDI to userColor
		set newName to ("LX " & theNumber)
		if userShowListNumber then set newName to ("LX " & userListNumber & "/" & theNumber)
		set q name of newMIDI to newName
		
		if q type of theSelection is "Group" and q type of parent of theSelection is "Cue List" then
			move cue id (uniqueID of newMIDI) to beginning of cue id (uniqueID of theSelection) of parent of theSelection
			if userNameParent then
				set parentName to q name of theSelection
				set q name of theSelection to parentName & " | " & newName
				if q color of theSelection is "None" then set q color of theSelection to userColor
			end if
			set selected to theSelection
		end if
		
		if userNameParent and q type of theParent is "Group" then
			set parentName to q name of theParent
			set q name of theParent to parentName & " | " & newName
			if q color of theParent is "None" then set q color of theParent to userColor
		end if
		
	on error
		return
	end try
end tell